Ansys contact 175

[FSOARESP]

I'm new in ansys and i'm trying to do some tutorials about contact elements. I'm using the contact 175 and targe170 but I'm always getting the same error.
Is there anyone that can help me? Probably is a simple mistake. My code is after the error message

Thanks in adavance,
Filipe

*** WARNING *** CP = 1.352 TIME= 20:42:18
Contact pair identified by real constant set 2 is missing contact
surface.

*** WARNING *** CP = 1.402 TIME= 20:42:18
Contact pair identified by real constant set 3 is missing target
surface.

*** WARNING *** CP = 1.422 TIME= 20:42:18
All selected contact pairs are initially open. Rigid body motion can
occur. You may use auto CNOF/ICONT by setting KEYOPT(5) to close
small gaps.

2 CONTACT PAIRS ARE SELECTED
CONTACT PAIR HAVING REAL ID = 2 IS INITIALLY OPEN
CONTACT PAIR HAVING REAL ID = 3 IS INITIALLY OPEN

----------------------------------------------------------------------------

Code:------------------------------------------------------------------------

finish
/clear
!
/title,Contact Elements
/PREP7
!
!Parameters
R1=60
R1p=130
R2=80
R2p=200
inter=1e-5
p=4500
E=2e5
nu=0.29
!
!create the geometry
k,1,0,0,0
k,2,R2,-R2,0
k,3,R2,-R2p,0
k,4,0,-R2p,0
k,5,0,-inter,0
k,6,R1,R1-inter,0
k,7,R1,R1p-inter,0
k,8,0,R1p-inter,0
k,9,0,-R2,0
k,10,0,R1-inter,0

l,2,3
l,3,4
l,4,1
larc,2,1,9,R2
l,6,7
l,7,8
l,8,5
larc,6,5,10,R1

al,5,6,7,8
al,1,2,3,4

VROTAT,1,,,,,,8,7,+90,0
VROTAT,2,,,,,,3,4,+90,0

!Create elements
!Structure
ET,1,solid92 !element type 1
MP,EX,1,E !Youngs's modulus
MP,NUXY,1,nu !Poisson's ratio
SMRT,1
VMESH,1,2

!TARGET
ET,2,targe170 !defines sec element, 2D C.E.
r,2,, !real default
TYPE,2 !sets this element type
real,2 !sets the real constants
!
asel,s,area,,9
nsla,s,1
nsel,r,loc,y,-2,0.5
cm,target,node
esurf

!Contact
allsel
ET,3,conta175 !defines sec element, 2D C.E.
r,3,,,,,,,,,,,,, !real default
TYPE,3 !sets this element type
real,3 !sets the real constants
!
asel,s,area,,5
nsla,s,1
nsel,r,loc,y,-0.5,1.5
cm,cont,node
TYPE,3 !sets this element type
real,3
esurf
allsel

!Boundary conditions
da,1,symm
da,2,symm
da,4,symm
da,8,symm
da,10,uy,0
fk,8,fy,-p/4

asel,s,area,,6
nsla,s,1
cm,topb,node
cp,1,UY,topb
allsel
!
cncheck

 

[CornishPasty]

Contact/target pairs should have the same reals.

!Contact
allsel
ET,3,conta175 !defines sec element, 2D C.E.
r,3,,,,,,,,,,,,, !real default

change the 3 to a 2 and have a go...