BOM API

[MHendler]

Hi,

Could you explain how to make a routine that just get the names of the level 1 components of an assembly?

Regards,

MHendler

 

[dsi]

Do you want to gather information from the drawing BOM or from the assembly? DimensionalSolutions@Core.com
While I welcome e-mail messages, please post all thread activity in these forums for the benefit of all members.

 

[dsi]

From an assembly:

'<><><><><><><><><><><><><><><><><><>
' List Top Level Parts in an Assembly
'<><><><><><><><><><><><><><><><><><>
Option Explicit

Const swDocASSEMBLY = 2

Sub Main()
    Dim swApp As Object
    Dim swAssy As Object
    Dim swConfig As Object
    Dim swRoot As Object
    Dim swComp() As Object
    Dim swChild As Object
    
    Dim sAssyName As String
    Dim i As Integer
    Dim ChildCount As Integer
    Dim sMsg As String

    Set swApp = CreateObject(&quot;SldWorks.Application&quot;)
    Set swAssy = swApp.ActiveDoc
    If (swAssy.GetType <> swDocASSEMBLY) Then
        swApp.SendMsgToUser &quot;You need to open an Assembly&quot;
        Exit Sub
    End If
    'Get Assy Name - Strip Extension
    sAssyName = swAssy.GetTitle
    If InStr(1, sAssyName, &quot;.&quot;) Then
        sAssyName = Left$(sAssyName, InStr(1, sAssyName, &quot;.&quot;) - 1)
    End If
    'Find the Root Component
    Set swConfig = swAssy.GetActiveConfiguration()
    Set swRoot = swConfig.GetRootComponent()
    swComp = swRoot.GetChildren
    'Find Children
    ChildCount = UBound(swComp) + 1
    sMsg = ChildCount & &quot; Items&quot;
    For i = 0 To (ChildCount - 1)
        Set swChild = swComp(i)
        sMsg = sMsg & vbCrLf & swChild.Name
    Next i
    'Report Results
    swApp.SendMsgToUser sMsg
    'Clean Up
    Set swChild = Nothing
    Set swRoot = Nothing
    Set swConfig = Nothing
    Set swAssy = Nothing
    Set swApp = Nothing
End Sub

Hope this helps... DimensionalSolutions@Core.com
While I welcome e-mail messages, please post all thread activity in these forums for the benefit of all members.