My 433MHz oscillator did not work!

[vanadium]

I am designing a 433MHz oscillator using a SAW resonator and a Philips wideband transistor BFT25A connected as a Colpitts circuit. The circuit is described by the PSPICE file as attached below. According to the PSPICE simulation results, the oscillating frequency was totally controlled by the LC values. The SAW device contributed no effect to the circuit. How can I make the circuit oscillate at 433.92MHz with high stability?

433MHz Oscillator
VCC  2  0  3V
L1   2  4  26nH
R2   2  5 150k
C3   4  6  12pF IC=3
C4   6  0  10pF IC=3
R3   6  0  3.9k
XSAW 5  0  NMR433A
XQ1  4  5  6  BFT25A
.LIB MYLIB.LIB 
.TRAN 10p 500n UIC
.OPTIONS ITL5=500000
.END

The PSPICE library "MYLIB.LIB" is attached as follows:

* My Own Library

* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
* 433.92MHz SAW Resonator, Unloaded Q = 12,800, Ceratronics Limited.
*
.subckt NMR433A 1 2
*
  rm    1       11      18
  lm	11	12	86.0075uH
  cm	12	2	1.56417fF
  cp	1	2	1.7pF
  cpar1 1       0       0.5pF
  cpar2 2       0       0.5pF
.ends
* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
* BFT25A SPICE MODEL
* PHILIPS SEMICONDUCTORS
* Date : September 1995
*
* PACKAGE : SOT23 DIE MODEL : BFT25A
* 1: COLLECTOR; 2: BASE; 3: EMITTER;
.SUBCKT BFT25A 1 2 3
Q1 6 5 7 7 QBFT25A
* SOT23 parasitic model
               Lb  4 5 0.4n 
               Le  7 8 0.83n
               L1  2 4 0.35n
               L2  1 6 0.17n
               L3  3 8 0.35n
              Ccb  4 6 71f
              Cbe  4 8 71f
*
* PHILIPS SEMICONDUCTORS                                     Version:   1.0
* Filename:   BFT25A.PRM                                     Date: Feb 1992
*
.MODEL  QBFT25A   NPN
+              IS = 1.37749E-017
+              BF = 8.56539E+001
+              NF = 9.79900E-001
+             VAF = 5.08049E+001
+             IKF = 1.00000E+001
+             ISE = 2.19977E-015
+              NE = 1.85715E+000
+              BR = 1.69751E+001
+              NR = 9.85511E-001
+             VAR = 2.49144E+000
+             IKR = 1.88014E-001
+             ISC = 2.05160E-016
+              NC = 1.10731E+000
+              RB = 8.00000E+001
+             IRB = 1.00000E-006
+             RBM = 8.00000E+001
+              RE = 7.91100E+000
+              RC = 5.30000E+000
+              EG = 1.11000E+000
+             XTI = 3.00000E+000
+             CJE = 2.23030E-013
+             VJE = 6.69700E-001
+             MJE = 5.96638E-002
+              TF = 5.11209E-012
+             XTF = 7.90917E+000
+             VTF = 1.33880E+000
+             ITF = 5.66263E-003
+             PTF = 1.53714E+001
+             CJC = 2.29018E-013
+             VJC = 3.94786E-001
.ENDS
* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
* end of library file

 

[lkm]

Hi,

The SAW doesnot contain any RLC component inside. SAW stand for surface acoustic wave. Inside the SAW their is a Glass or ceramic with 2 forks to transmite and recieive the ultra sound wave through the media.

The Q-value of SAW is very high. You can't implement it by RLC as the small size as SAW. The problem of SAW is high insertsion lost and the time delay may find in it.

The SPICE model is just a MODEL not the real. Just like the transistors' model does not contain any cap or R inside.

The SAW reject all the signal, taking about around 30db, except the frequency SAW's passband signal. I suggest you try to build the other SPICE circuit to figure out the respond of the SAW only. You will understand what I mean.

 

[vanadium]

I have tried another SPICE circuit in which an impluse was applied to the SAW resonator through a resistor. The resonator was expected to oscillate for a while after the exictation. However, it did not oscillate but just behaved as a capacitor.

How can I make the circuit oscillate at the frequency of the SAW resonator? Your help will be highly appreciated.

 

[jbartos]

Suggestion: If you happen to have mathematical model available then the oscillation occur if you have roots of the model on imaginary axis. To accomplish this a proper set of parameters, which position roots in complex plane, must be selected.
Visit:

http://www.giscafe.com/DACafe/EDATools/EDAbooks/SpiceHandBook/09_chapter08-01.html

http://www.uoguelph.ca/~antoon/circ/circuits.htm

http://www.qct.nl/theory/types.htm

http://www.ee.washington.edu/conselec/Sp96/projects/mst/final/circoper.htm

http://www.sss-mag.com/cosc.html

etc. for more info. Also, the following papers appear to be informative:
O. De Feo, G. M. Maggio, M. P. Kennedy: "The colpitts oscillator : families of periodic solutions and their bifurcations", I. Journal of Bifurcation and Chaos, Vol. 10, Nr 5, pp 935-958, 2000.
G.M. Maggio, O. De Feo, M. P. Kennedy: "Nonlinear analysis of the colpitts oscillator and applications to design", IEEE CAS Transactions on Circuits and systems I, Vol. 46, Nr 9, pp 1118-1130, 1999.