Solid model constraints not transferring to nodes

[robo1billion]

Hi,
This may be related to a recent question I posted regarding selecting geometric entities using their coordinates.

Using the APDL I first of all select a line using the LSEL command to apply a constraint.

Then I try to apply another constraint to a different line using LSEL again. However, this seems to overwrite the previously applied constraint on the other line. This can be seen by clicking on

List->Loads->DOF Constraints->On All Lines

I have made out a simplistic version of the problem below. The output window displays the following after the SOLVE command

"Constraint on undefined or unselected line 1 not transferred to nodes."

This doesn't happen if I manually select the lines. Does anyone know if there's something I'm missing out on here?

Thanks

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/CLEAR

/UNITS,SI

/prep7

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!CREATE GEOMETRY
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

CSYS, 0

K, 1, 0, 0, 0
K, 2, 0, 0, 50
K, 3, 200, 0, 50
K, 4, 200, 0, 0

K, 5, 0, 50, 0
K, 6, 0, 50, 50
K, 7, 200, 50, 50
K, 8, 200, 50, 0

V, 1, 2, 3, 4, 5, 6, 7, 8

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!CREATE MESH
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

ESIZE, 10

ET,1,SOLID92

MP, EX, 1, 3e9 MP, EZ, 1, 0.255e9
MP, GXY, 1, 0.38e9
MP, GYZ, 1, 0.38e9
MP, GXZ, 1, 0.38e9
MP, PRXY, 1, 0.022
MP, PRYZ, 1, 0.2
MP, PRXZ, 1, 0.45
MP, DENS, 1, 490

TYPE,1

VMESH, ALL

FINISH

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!SET BOUNDARY CONDITIONS AND SOLVE
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/SOLU
ANTYPE, STATIC

LSEL, S, LOC, X, 0, 0
LSEL, R, LOC, Y, 0, 0
LSEL, R, LOC, Z, 0, 50

DL, ALL, , ALL, 0

LSEL, S, LOC, X, 200, 200
LSEL, R, LOC, Y, 0, 0
LSEL, R, LOC, Z, 0, 50

DL, ALL, , UY, 0

ASEL, S, LOC, X, 0, 200
ASEL, R, LOC, Y, 0, 50
ASEL, R, LOC, Z, 0, 50

SFA, ALL, 1, PRES, 0.001

SOLVE ! Solve the problem

FINISH ! Finish the solution processor

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

(P.S. the reason the applied pressure if so low is because the problem will not solve otherwise. Rigid body motion occurs due to my problem applying the constraints)

 

[ansysfreak]

Dear roto1bilion

LSEL, S, LOC, X, 0, 0
LSEL, R, LOC, Y, 0, 0
LSEL, R, LOC, Z, 0, 50

DL, ALL, , ALL, 0
allsel,all,all
LSEL, S, LOC, X, 200, 200
LSEL, R, LOC, Y, 0, 0
LSEL, R, LOC, Z, 0, 50

DL, ALL, , UY, 0
allsel,all,all
ASEL, S, LOC, X, 0, 200
ASEL, R, LOC, Y, 0, 50
ASEL, R, LOC, Z, 0, 50

SFA, ALL, 1, PRES, 0.001
allsel,all,all

Regards
Garry

 

[robo1billion]

That sorted it!

Thanks Garry. Much appreciated.