Contact 171 element 1

[EricZhao]

I am trying to run a test problem involving Contact171 elements. It is a contact problem between two cantilevered beams. The upper beam bended over and touch the lower beam. But when I plot the von Mises stress, the lower beam has zero stress. It seems that I missed some settings for the contact pair. Here is my input:

/prep7
! Top Beam
*SET,X1,0
*SET,Y1,15
*SET,L1,100
*SET,H1,10
! Bottom Beam
*SET,X2,50
*SET,Y2,0
*SET,L2,100
*SET,H2,10
! Create Geometry
blc4,X1,Y1,L1,H1
blc4,X2,Y2,L2,H2
! define element type
ET,1,plane42 ! element type 1
keyopt,1,3,3 ! plane stress w/thick
type,1 ! activate element type 1
R, 1, 10 ! thickness 0.01
! define material properties
MP,EX, 1, 2000e3 ! Young's modulus
MP,NUXY,1, 0.3 ! Poisson's ratio
! meshing
esize,2 ! set meshing size
amesh,all ! mesh area 1
ET,2,contac48 ! defines second element type - 2D contact elements
keyo,2,7,1 ! contact time/load prediction
r,2,200000,,,,10
TYPE,2 ! activates or sets this element type
real,2 ! activates or sets the real constants
! define contact nodes and elements
! first the contact nodes
asel,s,area,,1 ! select top area
nsla,s,1 ! select the nodes within this area
nsel,r,loc,y,Y1 ! select bottom layer of nodes in this area
nsel,r,loc,x,X2,(X2+L2/2)! select the nodes above the other beam
cm,source,node ! call this group of nodes 'source'
! then the target nodes
allsel ! relect everything
asel,s,area,,2 ! select bottom area
nsla,s,1 ! select nodes in this area
nsel,r,loc,y,H2 ! select bottom layer of nodes in this area
nsel,r,loc,x,X2,(X2+L2/2)! select the nodes above the other beam
cm,target,node ! call this selection 'target'
gcgen,source,target,3 ! generate contact elements between defined nodes
allsel ! relect everything
finish
/solut
antype,0
time,1 ! Sets time at end of run to 1 sec
autots,on ! Auto time-stepping on
nsubst,100,1000,20 ! Number of sub-steps
outres,all,all ! Write all output
neqit,100 ! Max number of iterations
nsel,s,loc,x,X1 ! Constrain top beam
nsel,r,loc,y,Y1,(Y1+H1)
d,all,all
nsel,all
nsel,s,loc,x,(X2+L2) ! Constrain bottom beam
nsel,r,loc,y,Y2,(Y2+H2)
d,all,all
nsel,all
nsel,s,loc,x,(L1/2+X1) ! Apply load
nsel,r,loc,y,(Y1+H1)
f,all,fy,-100000
nsel,all
solve
finish

Did I missed something obvious?

Thanks a lot,

 

[meshparts]

Hi,

You are using Contact48 elements not Contact171 elements.

However the von mises stresses are not null.

After the solution copy/paste this in the command line:

/post1
set,last
PLNSOL,S,EQV,0,1
/contour,all,10,.551e-7,,2000
/replot

Regards,
Alex

PS: you mistyped /SOLU in your input code (/solut), see above.

 

[meshparts]

What Ansys version are you using? It seems that the old contac48 elements are no longer avalable in the 8.1 version that I am using.

In my opinion, the contact elements in your modell have too much penetration. You can see that if you set the display scale to 1 (/dscale,all,1). However I could't list the actual penetration for this elements.

I have used the conta175 point to surface elements insted of the contac48 elements. The penetration I get is relatively small (see input code below)


fini
/clear,start
/prep7
! Top Beam
*SET,X1,0
*SET,Y1,15
*SET,L1,100
*SET,H1,10
! Bottom Beam
*SET,X2,50
*SET,Y2,0
*SET,L2,100
*SET,H2,10
! Create Geometry
blc4,X1,Y1,L1,H1
blc4,X2,Y2,L2,H2
! define element type
ET,1,plane42 ! element type 1
keyopt,1,3,3 ! plane stress w/thick
type,1 ! activate element type 1
R, 1, 10 ! thickness 0.01
! define material properties
MP,EX, 1, 2000e3 ! Young's modulus
MP,NUXY,1, 0.3 ! Poisson's ratio
! meshing
esize,2 ! set meshing size
amesh,all ! mesh area 1
et, 2, conta175, , , , , , , 1, , , 1 ! contact algorithm: augmented lagrangian. (keyopt(2)=0)
! contact stiffness update: each substep based on mean stress of underlying elements
! from the previous substep. (keyopt(10)=1)
r, 2, , , 0.1, 0.01 ! Kontact stiffnes and penetration
et, 3, targe169 ! 2-d target element

TYPE,2 ! activates or sets this element type
real,2 ! activates or sets the real constants
! define contact nodes and elements
! first the contact nodes
asel,s,area,,1 ! select top area
nsla,s,1 ! select the nodes within this area
nsel,r,loc,y,Y1 ! select bottom layer of nodes in this area
nsel,r,loc,x,X2,(X2+L2/2)! select the nodes above the other beam
esurf ! generate contact elements
! then the target nodes
type,3 ! activate target elements
real,2 ! same real for the target elements!!
allsel ! relect everything
asel,s,area,,2 ! select bottom area
nsla,s,1 ! select nodes in this area
nsel,r,loc,y,H2 ! select bottom layer of nodes in this area
nsel,r,loc,x,X2,(X2+L2/2)! select the nodes above the other beam
esurf ! generate target elements
allsel ! relect everything
finish
/solu
antype,0
time,1 ! Sets time at end of run to 1 sec
autots,on ! Auto time-stepping on
nsubst,100,1000,20 ! Number of sub-steps
outres,all,all ! Write all output
neqit,100 ! Max number of iterations
nsel,s,loc,x,X1 ! Constrain top beam
nsel,r,loc,y,Y1,(Y1+H1)
d,all,all
nsel,all
nsel,s,loc,x,(X2+L2) ! Constrain bottom beam
nsel,r,loc,y,Y2,(Y2+H2)
d,all,all
nsel,all
nsel,s,loc,x,(L1/2+X1) ! Apply load
nsel,r,loc,y,(Y1+H1)
f,all,fy,-100000
nsel,all
solve
finish
/post1
set,last
PLNSOL,S,EQV,0,1
/contour,all,10,.551e-7,,2000
/dscale,all,1
/replot

 

[EricZhao]

Thanks mihaiupb. I am using 9.0. I am using this tutorial example to get myself familiar with contact elements.