Finite Element SuperElement

$$* ** DEC/CMS REPLACEMENT HISTORY, Element EXFE03.QAD
$$* ** *2 7-JUN-1995 14:09:35 CATHY "TO MODIFY THE COMMENT"
$$* ** *1 18-MAY-1995 12:39:40 CATHY "ALL TEST PROBLEMS WHICH WILL BE ON ALL RELEASE TAPE."
$$* ** DEC/CMS REPLACEMENT HISTORY, Element EXFE03.QAD
*TITLE 'EXFE03 - SUPERELEMENT BUILDING ANALYSIS'
STRUDL 'EXFE03' 'SUPERELEMENT BUILDING ANALYSIS'
$
$***********************************************************************
$* ** PROBLEM DESCRIPTION: Sample problem for Superelements. This
$* ** program is similar to the example found in
$* ** Section 2.3.11.7 of Volume 3 of the GTSTRUDL
$* ** User's Manual.
$***********************************************************************
$
UNIT FT KIPS
$
$ DEFINE JOINTS
$
JOINT COORDINATES
1 0. 0. 0. S
2 0. 0. 30. S
3 15. 0. 0. S
4 15. 0. 30. S
GENERATE 4 JOINTS ID 5 1 X 0. 0. Y 12. 0. Z 0. 10.
REPEAT 3 ID 4 X 5.
REPEAT 2 ID 16 Y 12.
$
$ DEFINE COLUMNS
$
TYPE SPACE FRAME
MEMBER INCIDENCES
1 1 5
2 2 8
3 3 17
4 4 20
GENERATE 2 MEMBERS ID 5 1 FROM 5 16 TO 21 16
REPEAT 1 ID 2 FROM 3 TO 3
REPEAT 1 ID 4 FROM 12 TO 12
$
$ DEFINE BEAMS
$
GENERATE 3 MEMBERS ID 13 1 FROM 5 1 TO 6 1
REPEAT 1 ID 3 FROM 12 TO 12
REPEAT 2 ID 6 FROM 16 TO 16
GENERATE 3 MEMBERS ID 31 1 FROM 5 4 TO 9 4
REPEAT 1 ID 3 FROM 3 TO 3
REPEAT 2 ID 6 FROM 16 TO 16
$
$ DEFINE FLOORS
$
TYPE PLATE
GENERATE 3 ELEMENTS ID 49 1 FROM 5 1 TO 6 1 TO 10 1 TO 9 1
REPEAT 2 ID 3 FROM 4 TO 4 TO 4 TO 4
REPEAT 2 ID 9 FROM 16 TO 16 TO 16 TO 16
$
$ MEMBER/ELEMENT PROPERTIES
$
UNITS INCHES POUNDS
CONSTANTS
E 3122000.
POISON 0.17
DENSITY 0.0868
MEMBER PROPERTIES PRISMATIC
1 TO 12 AX 200. IX 800. IY 2000. IZ 2000.
13 TO 48 AX 120. IX 400. IY 1000. IZ 1000.
ELEMENT PROPERTIES
49 TO 75 TYPE 'SBHQ6' THICK 8.
$
$ LOADING CONDITIONS
$
DEAD LOADING 1 'FRAME-DEAD' DIR -Y FACTOR 1. MEMBER 1 TO 48
LOADING 2 'ELEM-DEAD'
ELEMENT LOAD
49 TO 75 BODY FORCE GLOBAL BY -0.0868
LOADING COMBINATION 3 'DEAD LOAD' -
COMBINE 1 1. 2 1.
UNIT KIPS
LOADING 4 'WIND-Z'
JOINT LOAD
5 9 13 17 FORCE Z 5.
21 25 29 33 FORCE Z 5.
37 41 45 49 FORCE Z 10.
$
$ SUPERELEMENT DEFINITION
$
SUPERELEMENT DEFINITION
'ROOF' BOUNDARY NODES 37 40 49 52 MEMBERS 25 TO 30 43 TO 48 67 TO 75
'TRDFLO' BOUNDARY NODES 21 24 33 36 MEMBERS 19 TO 24 37 TO 42 58 TO 66
'SNDFLO' BOUNDARY NODES 5 8 17 20 MEMBERS 13 TO 18 31 TO 36 49 TO 57 -
SAME AS 'TRDFLO'
$
$ STIFFNESS ANALYSIS
$
DEVELOP STATIC PROPERTIES FOR SUPERELEMENT 'ROOF' 'TRDFLO'
PERFORM ASSEMBLY FOR STATICS
COMPUTE ALL DISPLACEMENTS
COMPUTE INTERNAL DISPLACEMENTS FOR SUPERELEMENT -
'ROOF' 'TRDFLO' 'SNDFLO' $ 'TRDFLO' MUST COME BEFORE 'SNDFLO'
COMPUTE GROSS RESULTS
LIST DISPLACEMETS,FORCES,REACTIONS
FINISH