Plate Bending Pinite Element example

*TITLE 'EXFE02 - PLATE BENDING TEST EXAMPLE'
STRUDL 'EXFE02' 'PLATE BENDING TEST EXAMPLE'
$
$***********************************************************************
$* ** PROBLEM DESCRIPTION: Sample problem for Finite Element Analysis.
$* ** This problem is similar to example 'FE-2'
$* ** in the GTSTRUDL User's Manual, Section
$* ** 2.3.9, Volume 3.
$***********************************************************************
$
UNITS KIPS INCHES
$
$ GENERATE A 2X2 MESH
$
$ MAKE ALL JOINTS SUPPORTED AND THEN FREE JOINT 5
$
GENERATE 3 JOINTS ID 1 1 X 60.0 0.0 Y 0.0 30.0 SUPPORT
MODIFY 2 ID 3 X -30.0 Y 0.0
$
STATUS FREE 5
$
TYPE PLATE BENDING
$
$ GENERATE 4 QUADRILATERAL ELEMENTS
$
GENERATE 2 ELEMENTS ID 1 1 FROM 1 1 TO 2 1 TO 5 1 TO 4 1
MODIFY 1 ID 2 FROM 3 TO 3 TO 3 TO 3
$
$ SPECIFY JOINT RELEASES TO SIMULATE ONE-QUARTER
$ OF A SIMPLY SUPPORTED PLATE
$
JOINT RELEASES
4 7 8 FORCE X FORCE Y
1 2 4 MOMENT Y
4 7 8 FORCE Z
8 9 6 MOMENT X
$
ELEMENT PROPERTIES
1 TO 4 TYPE 'BPHQ' THICKNESS 2.0
$
CONSTANTS
E 30000. ALL
POISSON 0.30 ALL
CTE 0.9E-05 ALL
$
LOADING 1 'UNIFORM LOAD'
ELEMENT LOADS
1 TO 4 SURFACE FORCES PZ -0.025
$
LOADING 2 'CENTER POINT LOAD'
JOINT LOAD
7 FORCE Z -10.0
$
LOAD 3 'TEMPERATURE GRADIENT'
JOINT 1 TO 9 TEMPERATURE GRADIENT Z 50.0
$
STIFFNESS ANALYSIS
$
LIST DISPLACEMENTS ALL
$
LIST STRESSES ALL
$
LIST SUM REACTIONS
$
CALCULATE AVERAGE STRESSES TOP
$
FINISH