P-delta effect example

STRUDL 'EXRC05' 'EXAMPLE JOB TO DEMONSTRATE P-DELTA ANALYSIS'
*TITLE 'EXRC05 - EXAMPLE JOB TO DEMONSTRATE P-DELTA ANALYSIS'
$
$***********************************************************************
$* ** PROBLEM DESCRIPTION: Sample problem for GTSTRUDL Reinforced
$* ** Concrete design.
$***********************************************************************
$
MATERIAL REINFORCED CONCRETE
METHOD ACI318-83

TYPE PLANE FRAME

UNITS FEET
JOINT COORDINATES
1 0. 8. S
2 12. 8. S
3 28. 0. S
4 40. 2. S
5 0. 20.
6 12. 20.
7 28. 20.
8 40. 20.
9 28. 32.
10 40. 32.

JOINT RELEASES
1 TO 4 MOMENT Z

MEMBER INCIDENCES
1 1 5
2 2 6
3 3 7
4 4 8
5 5 6
6 6 7
7 7 8
8 7 9
9 8 10
10 9 10

UNITS INCHES
MEMBER DIMENSIONS PRISMATIC
1 TO 4 8 9 RECT B 12 H 12
5 TO 7 10 RECT B 12 H 18

UNITS KIPS FEET
DEAD LOAD 'DL' -Y ALL MEMBERS
MEMBER LOADS
5 TO 7 FORCE Y UNIFORM FRAC W -0.144 LA 0.0 LB 1.0

LOAD 'LL'
MEMBER LOADS
5 TO 7 10 FORCE Y UNIFORM FRAC W -1.0 LA 0.0 LB 1.0
6 FORCE Y CONC FRAC P -100. L .25

LOAD 'WL'
JOINT LOADS
5 9 FORCE X 1.0
CINPUT

LOAD COMBINATION 1 COMBINE 'DL' 1.4 'LL' 1.4

LOAD COMBINATION 2 COMBINE 'DL' 1.05 'LL' 1.275 'WL' 1.275

LOAD COMBINATION 3 COMBINE 'DL' 0.9 'WL' 1.3

STIFFNESS ANALYSIS
cinput

LOAD LIST 1 2 3
LIST FORCES MEMBERS 3 6
LIST DISPLACEMENT JOINT 10

SLENDERNESS EFFECTS FOR COLUMNS 1 TO 4 8 9 BETAD 0.4
SLENDERNESS EFFECTS FOR BEAMS 5 TO 7 10 REDUCE I BY 50 PERCENT

CONVERGENCE TOLERANCE 0.001

PDELTA LOAD 'PD-1' COMBINE 1 1.0
PDELTA ANALYSIS NUMBER OF ITERATIONS 10

PDELTA LOAD 'PD-2' COMBINE 2 1.0
PDELTA ANALYSIS $ DEFAULT TO 1 ITERATION
LIST FORCES MEMBERS 3 6
PDELTA ANALYSIS CONTINUE NUMBER OF ITERATIONS 10

PDELTA LOAD 'PD-3' COMBINE 3 1.0
PDELTA ANALYSIS NUMBER OF ITERATIONS 10

LOAD LIST 'PD-1' 'PD-2' 'PD-3'
LIST FORCES MEMBERS 3 6
LIST DISPLACEMENT JOINT 10

FINISH