ISTRESS and TRANS126 element

[izyk]

Hi
Is there any posibility to perform a simulation with trans128 element and apply initial stress to other element (like shell181)? Ansys v10 gives an error that istress command can be used only for specific elements (shell181 included). However I apply a stres only on shell element, not on trans.

Here is the script:

FINISH
/CLEAR

/FILNAME,mem50shell,0
/CWD,'C:\temp\ANSYS'

!* membrane
Lm=300
Wm=300
Tm=5 !* Epaisseur de la membrane 3e-6 / 1e-6

dif=5
h=-1
V=0

!* membrane_division
b=20

/PREP7

ET,1,SHELL181
R,1,Tm

ET,2,TRANS126

MP,EX,1,130e+9*1e-6
MP,DENS,1,2330*1e-18
MP,PRXY,1,0.278

WPOFFS,0,0,dif
RECTNG,0,Lm,0,Wm
WPOFFS,0,0,-dif

LESIZE,ALL,,,b,-5

MSHAPE,0,2D
MSHKEY,1
AMESH,ALL

!* transducer

NSEL,S,LOC,Z,dif

CM,tr,NODE
ALLSEL,ALL

EMTGEN,'tr','EMTELM','EMTPNO','UZ',h,0,1E-02,0.8854E-05

NSEL,S,LOC,Z,dif+h
D,ALL,,0,,,,UZ
D,ALL,VOLT,v

CMSEL,S,TR
D,ALL,VOLT,0
ALLSEL,ALL

!* applying loads and BC

NSEL,S,LOC,X,0
NSEL,A,LOC,X,Lm
NSEL,A,LOC,Y,0
NSEL,A,LOC,Y,Wm

D,ALL,UX,0
D,ALL,UY,0
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
D,ALL,ROTZ,0

ALLSEL,ALL

SFA,1,1,pres,-101300*1E-6

FINISH

/SOLU
PSTRES,ON
istress,-20e+6*1e-6,-20e+6*1e-6,,,,,1

ANTYPE,STATIC
NLGEOM,ON

SOLVE
FINISH

save,mem50shell,db
fini

 

[Drej]

I believe your error comes from the fact that you have selected all elements when you issue the ISTRESS command. ISTRESS is applied to all currently selected elements, therefore you should use something like:

/SOLU
PSTRES,ON

esel,s,ename,,181 ! select just the SHELL181 elements

istress,-20e+6*1e-6,-20e+6*1e-6,,,,,1

allsel ! reselect everything

ANTYPE,STATIC
NLGEOM,ON

SOLVE
FINISH



------------
See faq569-1083 for details on how to make best use of Eng-Tips.com

 

[izyk]

it works, thanks