problems with modelling a piezo tube!!

[mat215]

Hi,

I'm working at the model of a piezo tube and I'm not satisfied with the behaviour of my tube. I tried to find all the mistakes I made in the matrices and I think they are now correct.
But the results compared with the descriptions from papers I read of "modelling piezo tubes" are not correct!

I'm applying a positive voltage at an electrode, which is a quarter of the tube, on the outer diameter. All nodes of the inner diameter are grounded. Now the tube should bend around the y-axes in the negative x-direction. In my model this works, but the behaviour of the tip of the tube isn't correct.

Maybe there is someone, who has already experiences in modeling with piezoelectrical materials and could give me some tips.

Regards Matthias



Here is my inputfile:

FINISH
/CLEAR

/PREP7


! MATERIAL PARAMETERS FROM DATA SHEET

! PARAMETERS FOR THE GEOMETRY OF THE PIEZO
OD = 6.35e-3 ! OUTER DIAMETER (m)
ID = 5.35e-3 ! INNER DIAMETER (m)
L = 10e-3 ! LENGTH OF THE TUBE
M = 4 ! NUMBER OF MESHED ROWS

ET,1,SOLID5,3 ! 3-D COUPLED-FIELD SOLID, PIEZO OPTION

MP,DENS,1,7760 ! DENSITY
MP,PERX,1,1110 ! PERMITTIVITY (X AND Y DIRECTION)
MP,PERZ,1,852 ! PERMITTIVITY (Z DIRECTION)

TB,PIEZ,1 ! DEFINE PIEZ. TABLE
TBDATA,16,12
TBDATA,14,12
TBDATA,3,-9.6
TBDATA,6,-9.6
TBDATA,9,15.1

TB,ANEL,1,,,0 ! DEFINE STRUCTURAL TABLE
TBDATA,1,1.076E11,6.312E10,6.385E10 ! INPUT [C] MATRIX
TBDATA,7,1.076E11,6.385E10
TBDATA,12,1.004E11
TBDATA,21,1.962E10
TBDATA,19,1.962E10
TBDATA,16,2.224E10

MAT,1
TYPE,1
CYL4,0,0,ID/2,0,ID/3+OD/6,0,L
CYL4,0,0,ID/3+OD/6,0,ID/6+OD/3,0,L
CYL4,0,0,ID/6+OD/3,0,OD/2,0,L
VGLUE,ALL

LSEL,S,LOC,X,ID/2 ! MESHING OF THE TUBE
LESIZE,ALL,0,0,m
LSEL,S,LOC,X,ID/3+OD/6
LESIZE,ALL,0,0,m
LSEL,S,LOC,X,ID/6+OD/3
LESIZE,ALL,0,0,m
LSEL,S,LOC,X,OD/2
LESIZE,ALL,0,0,m
VSWEEP,ALL

NSEL,S,LOC,Z,0 ! CLAMPED END OF THE TUBE
D,ALL,UX,0,,,,UY,UZ

LOCAL,1000,1 ! GROUNDED ELECTRODE AT INNER DIAMETER
NSEL,S,LOC,X,ID/2
D,ALL,VOLT,0

NSEL,S,LOC,X,OD/2 ! ELECTRODE AT OUTER DIAMETER
NSEL,R,LOC,y,-40,40
D,ALL,VOLT,10

CSDELE,1000

NSEL,ALL
FINISH

/SOLUTION
SOLVE
FINISH

 

[reno001]

Hi Matthias,

I found two mistakes:
- The relative permittivity must be multiply per the relative permittivity
- To select 1/4 of the outer cylinder must swap to Cylindrical coordinate system (see below):

1/__________________
MP,PERX,1,1110*8.854E-12 ! PERMITTIVITY X
MP,PERY,1,1110*8.854E-12 ! PERMITTIVITY Y !add this line don’t be leasy. :+)
MP,PERZ,1,852*8.854E-12 ! PERMITTIVITY Z

2/__________________
CSYS,1 ! Here, you specify the cylindrical coordinate system
NSEL,S,LOC,X,OD/2! ELECTRODE AT OUTER DIAMETER
NSEL,R,LOC,y,-40,40
D,ALL,VOLT,10
CSYS,0 ! Back to Cartesian as previously


Best Regards

Renaud