Why do my Performance settings change on their own in SW 2014?????

[dabiz7]

I am running Windows 7 Pro/ SP1 Intel i7-4770K 3.5 GHz 16 GB RAM workstation
My video card is a NVIDIA K2000D with 2 GB RAM

My problem is that I expected my display in SolidWOrks 2014 to be much more stable and very crisp and detailed, especially with only a few parts or a simple assembly. I have to go back in to my Options-Performance settings all the time because the keep moving on their own to lower (faster) settings, resulting in annoyingly faceted circles and edges. ANyone esle experinecing this?

I have had no luck with NVIDIA, they have no clue. I have set my Global and application settings for SolidWOrks to "Prefer maximum performance" int he NVIDIA setup app, but the settings in SolidWorks still are changin on their own. Anyone have a suggestred resolution or is this just a SW bug?

 

[ctopher]

I have not seen this. Maybe a better VC with more RAM.

Chris, CSWA
SolidWorks 14
ctopher's home
SolidWorks Legion

 

[TheTick]

Similar problem here w/ SW 2012 and ATI FirePro V4800.

 

[EEnd]

Here is a script that monitors the registry and lets you know when the value for the "Level of detail:" slider changes. When run, it pops up a MsgBox. For as long as that MsgBox is open, it listens for changes to the value associated with the slider and pops up a second message box letting you know that the value has changed. The code is specific to SW 2012, but can be adopted to other versions by modifying the keyPath string. Other options can be monitored by modifying the valueName string.

[link

http://files.engineering.com/getfil...7a-a034-067329a310cf&file=RegChangeTattle.vbs

]RegChangeTattle.vbs[/url]
Eric

const HKEY_USERS = &H80000003
strComputer = "."


'Get the SID of the current user.  This is necessary because HKEY_CURRENT_USER is not supported for
'registry change events. Using HKEY_USERS\\SID\\ instead.
Set wshShell = CreateObject("WScript.Shell")
strUsername = wshShell.ExpandEnvironmentStrings("%USERNAME%")
strDomain = wshShell.ExpandEnvironmentStrings("%USERDOMAIN%")
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set objAccount = objWMIService.Get("Win32_UserAccount.Name='" & strUsername & "',Domain='" & strDomain & "'")
SID = objAccount.SID


'Specify the value to be monitored
keyPath = SID & "\\Software\\SolidWorks\\Solidworks 2012\\Performance"
valueName = "Target Frame Rate"


'Get the initial value
Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
oReg.GetDWORDValue HKEY_USERS, keyPath, valueName, initialValue



'Set up the monitor
'Specify the sink for the event.
Set wmiSink = WScript.CreateObject("WbemScripting.SWbemSink", "SINK_") 

'Listen for changes to the value.
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\default")
queryStr = "SELECT * FROM RegistryValueChangeEvent  WHERE Hive='HKEY_USERS' AND " & _
        "KeyPath='" & keyPath & "' AND ValueName='" & valueName &"'"
objWMIService.ExecNotificationQueryAsync wmiSink, queryStr


'Use a MsgBox as the UI. The script halts here until ok is selected.
'It exits after ok is selected.
MsgBox "Listening for changes to: " & valueName & "." & vbCrLf & "Initial value: " & initialValue & "." & vbCrLf & vbCrLf & "Click OK to exit.", OKOnly, "Registry Change Monitor"


'The sink sub is called any time the event occurrs.
Sub SINK_OnObjectReady(wmiObject, wmiAsyncContext)
    oReg.GetDWORDValue HKEY_USERS, keyPath, valueName, newValue
    MsgBox valueName & " Changed." & vbCrLf & "New Value: " & newValue, 48, "Value Changed"
End Sub