How to set the stress 0 temperature from ANSYS thermal result 1

[JaneHe]

I am doing a thermal-stress analysis, and I first dsolve the thermal problem and got the temperature profile, which is supposed to be the stress 0 temperature profile for the component. Then I need to get the stress distribution when it cools down to room temperature. My problem is when I set the reference temperature is room temperature, B.C. temperature is from the ANSYS thermal result file, the result actually gives me the opposite deformation and stress value. I would like to get the results showing the actual deformation resulted from the temperature solved drops to room temperature, how can I do it?

 

[oelindoe]

Hi

I think u have to set TREF and TUNIF to the same temperature which should be stress free in LS1.

Then change TUNIF to room temp (or BF).

Eq:
/solu
tref,200
tunif,200
solve
tunif,20
solve

brgds

 

[JaneHe]

Thank you for the reply.
The problem is the temperature profile of stress 0 is not just one temperature value, it is a exponential curve alone the height direction.

 

[oelindoe]

Hi

So the temperature profile goes from like
100-200 DegC along the part and all of it should be
stressfree ?
I think u have to provide better info on this ?
brgds

 

[JaneHe]

Ok, the problem is I use a local heating source material to bond two components. During the bonding, the material and its attached solder will melt and bond to the components, which will cause only a thin layer of the components temperature increase. I can get the temperature profile for this process, in which, the stress of the solder and material should be stress 0 since it is in melting status. of course, the two components will have a little stress. Then, the temperature will all drop to room temperature, the solder solidify and stress no longer 0.
I model the first step, and get the stress distribution because of the temperature increase, but I don't know how to set the solder stress 0 for the second step, and how to use the temperature profile from the first step as the second step initial conditions.
Thanks

 

[oelindoe]

Hi
Funny. I have done something simular in another job.
Look at this example i got from another guy:
Brgds



!--snip

!solder material property

fini
/clear
/prep7

length=10
blc4,0,0,length,.1
blc4,0,.2,length,.05
blc4,0,.25,length,.05
blc4,.45,.1,.1,.1
blc4,.5*length,.1,.1,.1
blc4,length-.45,.1,.1,.1
aglue,all
et,1,42
asel,s,loc,y,.1,.2
esize,.01
amesh,all
esize,.03
asel,inve
amesh,all

asel,s,loc,y,0,.1
esla
emodif,all,mat,2
asel,s,loc,y,.2,.25
esla
emodif,all,mat,3
asel,s,loc,y,.25,.3
esla
emodif,all,mat,4
/pnum,mat,on
/number,1
alls

MPTEMP,,,,,,,,
MPTEMP,1,25
MPTEMP,2,170
MPTEMP,3,180
MPTEMP,4,260
MPDATA,EX,1,,30e3
MPDATA,EX,1,,30e3
MPDATA,EX,1,,1
MPDATA,EX,1,,1
MPDATA,prxy,1,,.3
MPDATA,prxy,1,,.3
MPDATA,prxy,1,,.3
MPDATA,prxy,1,,.3
TB,kinh,1,4,2,0
TBTEMP,25
TBpt,,1,30000
TBpt,,2,60000
TBTEMP,170
TBpt,,1,30000
TBpt,,2,60000
TBTEMP,180
TBpt,,1e-3,1e-3
TBpt,,2,1
TBTEMP,260
TBpt,,1e-3,1e-3
TBpt,,2,1

mp,alpx,1,20e-6,

mp,ex,2,1e6
mp,ex,3,1e6
mp,ex,4,1e6
mp,alpx,2,1e-7
mp,alpx,3,3e-7
mp,alpx,4,1e-7


! define load step and solution
/solu
nlgeom,on
d,node(0,0,0),all,0
d,node(length,0,0),uy,0
allsel,all
antype,0 ! static analysis

! 1st load step: from 260C to 180C solder solidification
tref,260
tunif,180
deltim,.25
solve

! 2nd load step: from 180C to 25C room temperature
tunif,25
solve

finish
/post1
/dscale,1,50
plns,u,sum

Rod Scholl
Senior Analysis and Simulation Engineer
Phoenix Analysis & Design Technologies
(602) 218 - 5391 (Direct to Amsterdam)
+31 62 023 0742 (European Cellphone)
Rod.Scholl@padtinc.com

http://www.padtinc.com